# Process this file with autoconf to produce a configure script.
#
# Copyright (C) 2017  Patrick McDermott
#
# This file is part of Timeteller.
#
# Timeteller is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# Timeteller is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with Timeteller.  If not, see <http://www.gnu.org/licenses/>.

AC_INIT([Timeteller], [0.1.0], [mailto:pj@pehjota.net], [Timeteller])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_SRCDIR([src/main.c])

AM_INIT_AUTOMAKE([gnu check-news dist-bzip2 dist-xz subdir-objects])
AM_SILENT_RULES([yes])

AM_CONDITIONAL([IN_GIT],
	[test -d "${srcdir}/.git" && command -v git >/dev/null 2>&1])

AC_PROG_CC()
AM_PROG_CC_C_O()
AC_PROG_CC_C99()

AX_CFLAGS_WARN_ALL()  dnl Adds -Wall or equivalent
AX_CHECK_COMPILE_FLAG([-Wpedantic], [AX_APPEND_FLAG([-Wpedantic])])
AX_CHECK_COMPILE_FLAG([-Wextra],    [AX_APPEND_FLAG([-Wextra])])

AC_ARG_ENABLE([gcc-warnings],
	[AS_HELP_STRING([--enable-gcc-warnings], [turn on many GCC warnings])],
	[case "${enableval}" in yes|no) gcc_warnings=${enableval};;
		*) AC_MSG_ERROR(
			[bad value ${enableval} for gcc-warnings option]);;
	esac],
	[
		gcc_warnings=no
		gl_GCC_VERSION_IFELSE([4], [6],
			[test -d "${srcdir}/.git" && gcc_warnings=yes])
	]
)
if test "x${gcc_warnings}" = 'xyes'; then
	nowarns=''
	nowarns="${nowarns} -Wsystem-headers"
	gl_MANYWARN_ALL_GCC([warns])
	gl_MANYWARN_COMPLEMENT([warns], [${warns}], [${nowarns}])
	for warn in ${warns}; do
		gl_WARN_ADD([${warn}])
	done
	AC_SUBST([WARN_CFLAGS])
fi

AX_CHECK_COMPILE_FLAG([-fdiagnostics-color=auto],
	[AX_APPEND_FLAG([-fdiagnostics-color=auto])])

AC_ARG_ENABLE([address-sanitization],
	[AS_HELP_STRING([--enable-address-sanitization],
		[turn on AddressSanitizer (if available)])],
	[case "${enableval}" in yes|no) address_sanitization=${enableval};;
		*) AC_MSG_ERROR(
			[bad value ${enableval} for address-sanitization option]
			);;
	esac],
	[
		address_sanitization=no
		gl_GCC_VERSION_IFELSE([4], [8],
			[test -d "${srcdir}/.git" && address_sanitization=yes])
	]
)
if test "x${address_sanitization}" = 'xyes'; then
	AX_CHECK_COMPILE_FLAG([-fsanitize=address],
		[AX_APPEND_FLAG([-fsanitize=address], [ASAN_CFLAGS])])
	AX_CHECK_COMPILE_FLAG([-fno-omit-frame-pointer],
		[AX_APPEND_FLAG([-fno-omit-frame-pointer], [ASAN_CFLAGS])])
	AC_SUBST([ASAN_CFLAGS])
fi

AC_CHECK_LIB([curses], [initscr],
	[CURSES_LIBS=-lcurses],
	[AC_MSG_ERROR([No library -lcurses found])])
AC_SUBST([CURSES_LIBS])
AC_CHECK_LIB([flite], [flite_init],
	[FLITE_LIBS=-lflite],
	[AC_MSG_ERROR([No library -lflite found])])
AC_SUBST([FLITE_LIBS])
AC_CHECK_LIB([flite_cmu_us_slt], [register_cmu_us_slt],
	[FLITE_CMU_US_SLT_LIBS=-lflite_cmu_us_slt],
	[AC_MSG_ERROR([No library -lflite_cmu_us_slt found])])
AC_SUBST([FLITE_CMU_US_SLT_LIBS])

AC_CONFIG_FILES([Makefile])
AC_CONFIG_HEADERS([config.h])
AC_OUTPUT()