# Process this file with autoconf to produce a configure script.
#
# Copyright (C) 2017  Patrick McDermott
#
# This file is part of Marquee.

# Marquee is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# Marquee is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with Marquee.  If not, see <http://www.gnu.org/licenses/>.

AC_INIT([Marquee], [0.1.0],
	[mailto:pj@pehjota.net], [marquee])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_SRCDIR([src/main.c])

AM_INIT_AUTOMAKE([gnu check-news dist-bzip2 dist-xz subdir-objects])
AM_SILENT_RULES([yes])

AM_CONDITIONAL([IN_GIT],
	[test -d "${srcdir}/.git" && command -v git >/dev/null 2>&1])

AC_PROG_CC()
AM_PROG_CC_C_O()

AX_CHECK_COMPILE_FLAG([-std=c99], [CFLAGS="${CFLAGS} -std=c99"], [], [])

# Consider also:
#   * -Wchkp
#   * -Wformat=2
#   * -Wnull-dereference
#   * -Winit-self
#   * -Wmissing-include-dirs
#   * etc.
# Cf. <https://gcc.gnu.org/onlinedocs/gcc/Warning-Options.html> and
# <http://git.pehjota.net/overworld-rpg/overworld-rpg.git/tree/configure.ac#n60>
m4_foreach_w([WARN],
	[
		-Wpedantic -Wall -Wextra
	], [
		AX_CHECK_COMPILE_FLAG([WARN], [CFLAGS="${CFLAGS} WARN"], [], [])
	]
)

AX_CHECK_COMPILE_FLAG([-fdiagnostics-color=auto],
	[CFLAGS="${CFLAGS} -fdiagnostics-color=auto"], [], [])

PKG_PROG_PKG_CONFIG()
PKG_CHECK_MODULES([GTK], [gtk+-3.0])
PKG_CHECK_MODULES([WEBKIT2GTK], [webkit2gtk-4.0])
GTK_CFLAGS="$(printf ' %s' "${GTK_CFLAGS}" | \
	sed 's/ -I/ -isystem/g;')"
WEBKIT2GTK_CFLAGS="$(printf ' %s' "${WEBKIT2GTK_CFLAGS}" | \
	sed 's/ -I/ -isystem/g;')"

AC_ARG_ENABLE(
	[debug],
	[AS_HELP_STRING([--enable-debug], [enable debugging])],
	,
	[enable_debug=no])

if test "x${enable_debug}" = 'xyes'; then
	AC_SEARCH_LIBS([logl], [m], [],
		[AC_MSG_ERROR([unable to find the logl() function])])
	AC_DEFINE([MQ_TREE_DEBUG], [1], [Define to 1 to enable tree debugging.])
else
	AC_DEFINE([MQ_TREE_DEBUG], [0], [Define to 1 to enable tree debugging.])
fi

AC_CONFIG_FILES([Makefile])
AC_CONFIG_HEADERS([config.h])
AC_OUTPUT()