# Process this file with autoconf to produce a configure script.
#
# Copyright (C) 2017  Patrick McDermott
#
# This file is part of Marquee.

# Marquee is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# Marquee is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with Marquee.  If not, see <http://www.gnu.org/licenses/>.

AC_INIT([Marquee], [0.1.0],
	[mailto:pj@pehjota.net], [marquee])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_SRCDIR([src/main.c])

AM_INIT_AUTOMAKE([gnu check-news dist-bzip2 dist-xz subdir-objects])
AM_SILENT_RULES([yes])

AM_CONDITIONAL([IN_GIT],
	[test -d "${srcdir}/.git" && command -v git >/dev/null 2>&1])

GETTEXT_PACKAGE="${PACKAGE}"
AC_SUBST([GETTEXT_PACKAGE])
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["${GETTEXT_PACKAGE}"],
	[Define the gettext package to be used.])
AM_GLIB_GNU_GETTEXT()

AC_PROG_CC()
AM_PROG_CC_C_O()
AC_PROG_LN_S()

AX_CHECK_COMPILE_FLAG([-std=c11], [CFLAGS="${CFLAGS} -std=c11"], [
	AX_CHECK_COMPILE_FLAG([-std=c1x], [CFLAGS="${CFLAGS} -std=c1x"], [], [])
], [])

AX_CFLAGS_WARN_ALL()  dnl Adds -Wall or equivalent
AX_CHECK_COMPILE_FLAG([-Wpedantic], [AX_APPEND_FLAG([-Wpedantic])])
AX_CHECK_COMPILE_FLAG([-Wextra],    [AX_APPEND_FLAG([-Wextra])])

AC_ARG_ENABLE([gcc-warnings],
	[AS_HELP_STRING([--enable-gcc-warnings], [turn on many GCC warnings])],
	[case "${enableval}" in yes|no) gcc_warnings=${enableval};;
		*) AC_MSG_ERROR(
			[bad value ${enableval} for gcc-warnings option]);;
	esac],
	[
		gcc_warnings=no
		gl_GCC_VERSION_IFELSE([4], [6],
			[test -d "${srcdir}/.git" && gcc_warnings=yes])
	]
)
if test "x${gcc_warnings}" = 'xyes'; then
	nowarns=''
	nowarns="${nowarns} -Wsystem-headers"
	gl_MANYWARN_ALL_GCC([warns])
	gl_MANYWARN_COMPLEMENT([warns], [${warns}], [${nowarns}])
	for warn in ${warns}; do
		gl_WARN_ADD([${warn}])
	done
	AC_SUBST([WARN_CFLAGS])
fi

AX_CHECK_COMPILE_FLAG([-fdiagnostics-color=auto],
	[AX_APPEND_FLAG([-fdiagnostics-color=auto])])

AC_ARG_ENABLE([address-sanitization],
	[AS_HELP_STRING([--enable-address-sanitization],
		[turn on AddressSanitizer (if available)])],
	[case "${enableval}" in yes|no) address_sanitization=${enableval};;
		*) AC_MSG_ERROR(
			[bad value ${enableval} for address-sanitization option]
			);;
	esac],
	[
		address_sanitization=no
		gl_GCC_VERSION_IFELSE([4], [8],
			[test -d "${srcdir}/.git" && address_sanitization=yes])
	]
)
if test "x${address_sanitization}" = 'xyes'; then
	AX_CHECK_COMPILE_FLAG([-fsanitize=address],
		[AX_APPEND_FLAG([-fsanitize=address], [ASAN_CFLAGS])])
	AX_CHECK_COMPILE_FLAG([-fno-omit-frame-pointer],
		[AX_APPEND_FLAG([-fno-omit-frame-pointer], [ASAN_CFLAGS])])
	AC_SUBST([ASAN_CFLAGS])
fi

PKG_PROG_PKG_CONFIG()
PKG_CHECK_MODULES([GTK], [gtk+-3.0])
PKG_CHECK_MODULES([WEBKIT2GTK], [webkit2gtk-4.0])
PKG_CHECK_MODULES([LIBRSVG], [librsvg-2.0])
GTK_CFLAGS="$(printf ' %s' "${GTK_CFLAGS}" | \
	sed 's/ -I/ -isystem/g;')"
WEBKIT2GTK_CFLAGS="$(printf ' %s' "${WEBKIT2GTK_CFLAGS}" | \
	sed 's/ -I/ -isystem/g;')"
LIBRSVG_CFLAGS="$(printf ' %s' "${LIBRSVG_CFLAGS}" | \
	sed 's/ -I/ -isystem/g;')"

AC_ARG_ENABLE(
	[debug],
	[AS_HELP_STRING([--enable-debug], [enable debugging])],
	,
	[enable_debug=no])
if test "x${enable_debug}" = 'xyes'; then
	AX_CHECK_COMPILE_FLAG([-O0], [AX_APPEND_FLAG([-O0])])
	AC_SEARCH_LIBS([logl], [m], [],
		[AC_MSG_ERROR([unable to find the logl() function])])
	AC_DEFINE([MQ_TREE_DEBUG], [1], [Define to 1 to enable tree debugging.])
else
	AC_DEFINE([MQ_TREE_DEBUG], [0], [Define to 1 to enable tree debugging.])
fi

AC_ARG_ENABLE(
	[in-place],
	[AS_HELP_STRING([--enable-in-place],
		[run executable in place from build directory])],
	,
	[enable_in_place=no])
if test "x${enable_in_place}" = 'xyes'; then
	AC_DEFINE([RUN_IN_PLACE], [1],
		[Define to 1 to run executable in place from build directory.])
else
	AC_DEFINE([RUN_IN_PLACE], [0],
		[Define to 1 to run executable in place from build directory.])
fi

AC_CONFIG_FILES([Makefile data/Makefile po/Makefile.in])
AC_CONFIG_HEADERS([config.h])
AC_OUTPUT()